Ham radio field box arduino controller :)

//vk2fro field box controller. For Sigurthrs benefit I have commented
// the code. The double slases are like rem statements in basic

#include <max6675.h>
#include <LiquidCrystal.h>
#include <Wire.h>

// the above 3 commands tell the programming environment to include
// modules, which are like subroutines. (gosub, return)

int thermoDO = 4;
int thermoCS = 5;
int thermoCLK = 6;
float tmp = 0;

//the above initialize variables. in basic this 
//might be "let tmp=0".

MAX6675 thermocouple(thermoCLK, thermoCS, thermoDO);
int fanPin = A2;
int hfPin = A0;
int vhfPin = A1;

//The above defines the pins for the MAX 6675 chip 
//and the relays

LiquidCrystal lcd(8, 9, 10, 11, 12, 13);

//and this one above sets the LCD output pins


uint8_t degree[8]  = {140,146,146,140,128,128,128,128};
// make a cute degree symbol for the lcd

// below we begin our initialization. This part only 
// runs once.
void setup() {
  Serial.begin(9600); //debugging port
  pinMode(fanPin, OUTPUT); digitalWrite(fanPin, HIGH); 
// ensure fans are off on power up.
  pinMode(hfPin, OUTPUT); digitalWrite(hfPin, HIGH); 
// turn off the hf rig
  pinMode(vhfPin, OUTPUT); digitalWrite(vhfPin, HIGH); 
// turn off the vhf rig
//above 3 set up the relay pins, for the fans and the two radios.
  lcd.begin(16, 2); //initializes the LCD, 16x2 character.
  lcd.createChar(0, degree); 
//Actually creates the ° Symbol in memory at byte 
//position 0 in the LCD.
  lcd.setCursor(0,0); 
//Throws the cursor to line 1, position 1
  delay(500); 
// give lcd a chance to complete initilization
  lcd.print("Powering up..."); // prints to LCD
  lcd.setCursor(0,1); 
  lcd.print("HF:OFF   VHF:OFF");
  delay(3000); 
// waits 3 seconds for everything to settle
  digitalWrite(hfPin, LOW); 
//Turns on Relay one, and thus the FT-950
  lcd.setCursor(0,1); 
//Moves the cursor back to pos 1, line 1.
// LCD's are always in overwrite mode, 
//so we'll just write over the top :)
  lcd.print("HF:ON    VHF:OFF");
  delay(5000); 
// 5 second delay to prevent inrush blowing fuses. 
// The FT-950 has about a 3 second startup, Gives it time to settle.
  lcd.setCursor(0,1);
  lcd.print("HF:ON    VHF:ON ");
  digitalWrite(vhfPin, LOW); 
// Power up the 2nd relay, and the VHF rig.
  delay(3000); 
// 3 second delay, let stuff stabilize
  lcd.clear(); 
//Clear the LCD
  lcd.setCursor(0, 0);
  lcd.print("VKFRO FIELD BOX"); 
// we wont use line 1 anymore, so we can print this here :)
  lcd.setCursor(8,1); 
// move to line 2, position 8
  lcd.print("Fan: Off"); 
//Print "Fans are off"
}

//Below is the main program. Loops over ad infinitum.
void loop() {
  lcd.setCursor(0,1);
  tmp=thermocouple.readCelsius(); 
// Reads the max 6675 
  lcd.print(tmp);
// below: work out where the degree symbol must go,
// and print it.
#if ARDUINO >= 100
  lcd.write((byte)0);
#else
  lcd.print(0, BYTE);
#endif
  lcd.print("C ");
  lcd.setCursor(8,1);
  if (tmp >= 40){ digitalWrite(fanPin, LOW); lcd.print("Fan: On ");
//line above checks to see if its hotter than 40°C, 
//and if so, turn on the fan.
  }
  if (tmp <= 30){digitalWrite(fanPin, HIGH); lcd.print("Fan: Off");
// Line above turns off the fan below 30°C
  }
  delay(500); 
// without this delay the processor would run so fast
// it would overload and probably kill the max 6675;
// a $9 chip!
}